file in_1

/* train of mEPC's */

dt = 1.0e-6
it = 20000

kp = 1.35e8
km = 64286
alpha = 1250
beta = 48750
AChR_density = 7250
n = 7000

kpe = 1.5e8
kme = 3750
AChE_density = 2000

D = 2.1e-6

Rex = 2.5
cleft = 0.05

TIME_STEP = dt
ITERATIONS = it
EFFECTOR_GRID_DENSITY = 10000

DEFINE_LIGAND ACh {
  DIFFUSION_CONSTANT = D
}

DEFINE_REACTION AChR {
  R[>ARs{kp:+ACh,POSITIVE_POLE}][>ARt{kp:+ACh,POSITIVE_POLE}]
  ARs[>R{km:-ACh,POSITIVE_POLE}][>A2Rc{kp:+ACh,POSITIVE_POLE}]
  ARt[>R{km:-ACh,POSITIVE_POLE}][>A2Rc{kp:+ACh,POSITIVE_POLE}]
  A2Rc[>A2Ro{beta}][>ARs{km:-ACh,POSITIVE_POLE}][>ARt{km:-ACh,POSITIVE_POLE}]
  A2Ro[>A2Rc{alpha}]
  REFERENCE_STATE R {
    ACh NUMBER_BOUND = 0
  }
}

DEFINE_REACTION AChE {
  E[>AE{kpe:+ACh,POSITIVE_POLE}]
  AE[>E{kme:#ACh}]
  REFERENCE_STATE E {
    ACh NUMBER_BOUND = 0
  }
}

DEFINE_RELEASE_PATTERN short_train {
  DELAY = 0
  RELEASE_INTERVAL = 4.0e-3
  TRAIN_INTERVAL = 1
  TRAIN_DURATION = 8.01e-3
  NUMBER_OF_TRAINS = 1
}

INSTANTIATE nmj OBJECT {
  ACh_release_site SPHERICAL_RELEASE_SITE {
    LOCATION = [0,0,0]
    LIGAND = ACh
    NUMBER_TO_RELEASE = n
    SITE_DIAMETER = cleft
    RELEASE_PATTERN = short_train
  }
  synaptic_cleft BOX {
    CORNERS = [-Rex,-Rex,-cleft/2], [Rex,Rex,cleft/2]
    FULLY_CLOSED = YES
    ADD_EFFECTOR {
      STATE = AChR.R
      DENSITY = AChR_density
      ELEMENT = BOTTOM
      POLE_ORIENTATION = POSITIVE_BACK
    }
    ADD_EFFECTOR {
      STATE = AChE.E
      DENSITY = AChE_density
      ELEMENT = BOTTOM
      POLE_ORIENTATION = POSITIVE_BACK
    }
  }
}

REACTION_DATA_OUTPUT {
  STEP = 1.0*dt
  { COUNT[ACh,nmj,FOR_EACH_TIME_STEP] } => INPUT_FILE & ".ACh"
  { COUNT[AChR.R,WORLD,FOR_EACH_TIME_STEP] } => INPUT_FILE & ".R"
  { COUNT[AChR.ARs,WORLD,FOR_EACH_TIME_STEP] + COUNT[AChR.ARt,WORLD,FOR_EACH_TIME_STEP] } => INPUT_FILE & ".AR"
  { COUNT[AChR.A2Rc,WORLD,FOR_EACH_TIME_STEP] } => INPUT_FILE & ".A2Rc"
  { COUNT[AChR.A2Ro,WORLD,FOR_EACH_TIME_STEP] } => INPUT_FILE & ".A2Ro"
}